For the readers who are interested in Erlang distribution, we have prepared another specific image (see right). Note that in Erlang distribution the shape parameter k must take integers.

Originally, the pdf of Gamma distribution is

${\displaystyle f(x;k,\theta )={\frac {x^{k-1}e^{-{\frac {x}{\theta }}}}{\theta ^{k}\Gamma (k)}}.}$

Let α = k, and β = 1/θ. Then

${\displaystyle f(x;k,\theta )=f(x;\alpha ,1/\beta )={\frac {\beta ^{\alpha }x^{\alpha -1}e^{-\beta x}}{\Gamma (\alpha )}}.}$

Hence

${\displaystyle \ln f(x;k,\theta )=\alpha \ln \beta +(\alpha -1)\ln x-\ln \Gamma (\alpha )-\beta x}$

which directly gives the code below.

 

Aquesta imatge vectorial ha estat creada amb Gnuplot.

# Author: Autopilot, Ika
# Date: 12/08/2014

set term svg size 800,600 font 'Times, 24' enhanced
set output 'gamma_dist_pdf.svg'
set samples 1001

set xtics 0,2
set ytics 0,0.1
set mxtics 10
set mytics 10
set yrange [0:0.5]
set key top right Left reverse

# Ln f(x; k, theta)
# Commonly, we denote a = alpha = k and b = beta = 1/theta.
ln_f(x, a, b) = a*log(b) - lgamma(a) + (a-1)*log(x) - b*x

# f(x; k, theta)
f(x, k, theta) = (x<0)? 0 : (x==0)? ((k<1)? 1/0 : (k==1)? theta : 0)\
 : (theta==0)? 0 : exp(ln_f(x, k, 1.0/theta))

plot [0:20] \
    f(x, 1.0, 2.0) t "k = 1.0, {/Symbol q} = 2.0" lw 2 lc rgb "red", \
    f(x, 2.0, 2.0) t "k = 2.0, {/Symbol q} = 2.0" lw 2 lc rgb "orange", \
    f(x, 3.0, 2.0) t "k = 3.0, {/Symbol q} = 2.0" lw 2 lc rgb "yellow", \
    f(x, 5.0, 1.0) t "k = 5.0, {/Symbol q} = 1.0" lw 2 lc rgb "green", \
    f(x, 9.0, 0.5) t "k = 9.0, {/Symbol q} = 0.5" lw 2 lc rgb "black", \
	f(x, 7.5, 1.0) t "k = 7.5, {/Symbol q} = 1.0" lw 2 lc rgb "blue", \
	f(x, 0.5, 1.0) t "k = 0.5, {/Symbol q} = 1.0" lw 2 lc rgb "purple"

set term x11
set output

Això és una imatge retocada, cosa que vol dir que ha estat alterada digitalment de la seva versió original. Modificacions: Recreated as svg with gnuplot. L'original es pot veure a: Gamma distribution pdf.png: . Modificacions fetes per Autopilot.

Jo, el titular dels drets d'autor d'aquest treball, el public sota les següents llicències:

	Aquest fitxer està subjecte a la llicència de Creative Commons Reconeixement i Compartir Igual 3.0 No adaptada.
	Sou lliure de: compartir – copiar, distribuir i comunicar públicament l'obra adaptar – fer-ne obres derivades Amb les condicions següents: reconeixement – Heu de donar la informació adequada sobre l'autor, proporcionar un enllaç a la llicència i indicar si s'han realitzat canvis. Podeu fer-ho amb qualsevol mitjà raonable, però de cap manera no suggereixi que l'autor us dóna suport o aprova l'ús que en feu. compartir igual – Si modifiqueu, transformeu, o generareu amb el material, haureu de distribuir les vostres contribucions sota una llicència similar o una de compatible com l'original
	Aquest avís de llicència s'ha afegit a aquest fitxer d'acord amb l'actualització de la llicència GFDL.http://creativecommons.org/licenses/by-sa/3.0/CC BY-SA 3.0Creative Commons Attribution-Share Alike 3.0truetrue

S'autoritza la còpia, la distribució i la modificació d'aquest document sota els termes de la llicència de documentació lliure GNU versió 1.2 o qualsevol altra versió posterior que publiqui la Free Software Foundation; sense seccions invariants, ni textos de portada, ni textos de contraportada. S'inclou una còpia d'aquesta llicència en la secció titulada GNU Free Documentation License.http://www.gnu.org/copyleft/fdl.htmlGFDLGNU Free Documentation Licensetruetrue

Aquest treball és programari lliure. Podeu redistribuir-lo i modificar-lo sota els termes de la Llicència Pública General GNU (GNU GPL), publicada per la Free Software Foundation; en la seva versió número 2 o en qualsevol posterior. Aquesta obra es distribueix sota l'esperança que sigui d'utilitat, però sense cap mena de garantia, fins i tot sense la garantia implícita de comercialització o d'adequació per a un propòsit particular. Vegeu els texts de la versió 2 i de la versió 3 de la GNU GPL per a més detalls.http://www.gnu.org/licenses/gpl.htmlGPLGNU General Public Licensetruetrue

Podeu seleccionar la llicència que vulgueu.

This image is a derivative work of the following images:

• File:Gamma_distribution_pdf.png licensed with Cc-by-sa-3.0-migrated, GFDL, GPL
  • 2005-03-10T20:34:05Z MarkSweep 1300x975 (162472 Bytes) new version of PDF and matching CDF
  • 2005-03-10T17:45:44Z Cburnett 960x720 (138413 Bytes) Probability density function for the Gamma distribution {{GFDL}}

Uploaded with derivativeFX