File:Dueling lightsabers.svg és una versió vectorial (SVG) d'aquest fitxer. En cas de ser millor, hauria de ser emprada en lloc d'aquesta imatge tramada. File:Fighting lightsabres.jpg → File:Dueling lightsabers.svg Per a més informació pel que fa als gràfics vectorials, llegiu la transició a SVG en Commons. També hi ha informació quant a la compatibilitat del MediaWiki amb les imatges SVG. En altres idiomes Alemannisch ∙ Bahasa Indonesia ∙ Bahasa Melayu ∙ British English ∙ català ∙ čeština ∙ dansk ∙ Deutsch ∙ eesti ∙ English ∙ español ∙ Esperanto ∙ euskara ∙ français ∙ Frysk ∙ galego ∙ hrvatski ∙ Ido ∙ italiano ∙ lietuvių ∙ magyar ∙ Nederlands ∙ norsk bokmål ∙ norsk nynorsk ∙ occitan ∙ Plattdüütsch ∙ polski ∙ português ∙ português do Brasil ∙ română ∙ Scots ∙ sicilianu ∙ slovenčina ∙ slovenščina ∙ suomi ∙ svenska ∙ Tiếng Việt ∙ Türkçe ∙ vèneto ∙ Ελληνικά ∙ беларуская (тарашкевіца) ∙ български ∙ македонски ∙ нохчийн ∙ русский ∙ српски / srpski ∙ татарча/tatarça ∙ українська ∙ ქართული ∙ հայերեն ∙ বাংলা ∙ தமிழ் ∙ മലയാളം ∙ ไทย ∙ 한국어 ∙ 日本語 ∙ 简体中文 ∙ 繁體中文 ∙ עברית ∙ العربية ∙ فارسی ∙ +/−

 

Resum

DescripcióFighting lightsabres.jpg	Dansk: Tegning af et blåt og rødt lyssværd, der fægter. Kan bruges som et ikon. English: Drawing of a red and a blue lightsaber fighting. Can be used as an icon. Italiano: Immagine raffigurante due spade laser incrociate, una rossa e una blu. Può essere usata come icona
Data	19 d'octubre de 2006
Font	Treball propi
Autor	Søren Peo Pedersen
Permís (Com reutilitzar aquest fitxer)	Public domainPublic domainfalsefalse Jo, el titular del copyright d'aquesta obra, l'allibero al domini públic. Això s'aplica a tot el món. En alguns països això pot no ser legalment possible, en tal cas: Jo faig concessió a tothom del dret d'usar aquesta obra per a qualsevol propòsit, sense cap condició llevat d'aquelles requerides per la llei.
Altres versions	Dueling lightsabers.svg

POV-Ray code

Peo's version is made using the Persistence of Vision Raytracer, or "POV-Ray" for short. Use the code below to have this program render this image in any desired size/resolution:

global_settings {max_trace_level  10}

#declare HandleMetal=texture {pigment {color rgb .5} // Metal for end
  finish {ambient .4 reflection .6 phong 1 metallic} // parts of handle 
  }
  
#macro Saber(BeamColor) // Renders one saber with specified beam color
union {
  // Parts forming the handle:
  cone {<0,-4,0>,.05,<0,-3.9,0>,.17 texture {HandleMetal}}
  cylinder {<0,-3.9,0>,<0,-3.85,0>,.17 texture {HandleMetal}}
  cone {<0,-3.85,0>,.17,<0,-3.83,0>,.15 texture {HandleMetal}}
  cylinder {<0,-3.83,0>,<0,-2.3,0>,.15 pigment {color rgb .5} finish {ambient .4}}
  cone {<0,-2.3,0>,.17,<0,-2.28,0>,.15 open texture {HandleMetal}}
  cylinder {<0,-2.28,0>,<0,-2.26,0>,.17 open texture {HandleMetal}}
  cone {<0,-2.26,0>,.17,<0,-2.01,0>,.1 open texture {HandleMetal}}
  
  // The beam:
  cylinder {<0,-2,0>,<0,4,0>,1
    pigment {color rgbt 1}
    hollow
    interior {
      media {
        intervals 10 samples 10,100 confidence 0.9  // Settings re-
        variance 1.0/128 ratio 0.9 // garding the "glowing" beam
        absorption rgb <1,1,1>-BeamColor
        method 3
        density {
          cylindrical
          density_map {           // Density: Most dense along
            [0 color rgb 0]       // the axis, or "center", of
            [.4 color rgb .0625]  // the beam; fading off at
            [.5 color rgb .125]   // greater distances from the
            [.6 color rgb .25]    // beam.
            [.7 color rgb .5]
            [.8 color rgb 1]
            [.9 color rgb 2]
            [1 color rgb 10]
            } // End of density_map
          } // End of density
        } // End of media
      } //end of interior
    } //end of "beam" cylinder
  } // End of entire saber definition:
#end

#declare Spotty=pigment { // Pattern for "spotty
  bumps                   // surroundings", to
  color_map {             // make metals look
    [0 color rgb 0]       // "really metallic".
    [1 color rgb 1]
    }
  scale .3
  }
 
sky_sphere {pigment { // Combine spotty pattern
  gradient z          // with a neutral, white
  pigment_map {       // background for the a-
    [0 Spotty]        // rea the camera "sees".
    [.884 Spotty]
    [.884 color rgb 1]
    [1 color rgb 1]
    }
  translate -.5
  scale 2
  }}

#object {Saber(<1,.3,.1>) rotate <0,0,-53>}
#object {Saber(<.1,.3,1>) rotate <0,0,53>}

camera {
  location <0,0,-5.5>
  look_at 0
  }

light_source {<-100,200,-150> color rgb 1}
light_source {<200,150,100> color rgb 1}